Form Field Validation via Regular Expressions

<%
Function Validate_Input(Expression,Pattern)
	
	Dim objRegExp
		
	if Expression <> "" and Pattern <> "" then
		
		Set objRegExp = New RegExp
			
		select case (Pattern)
			
			case "US_PHONE"
			' sample matches: 1-(123)-123-1234 / 123 123 1234 / 1-800-ALPHNUM 
			' sample non-matches: 1.123.123.1234 / (123)-1234-123 / 123-1234 
			
				objRegExp.Pattern		= "^([0-9]( |-)?)?(\(?[0-9]{3}\)?|[0-9]{3})( |-)?([0-9]{3}( |-)?[0-9]{4}|[a-zA-Z0-9]{7})$"
					
			case "US_DATE"
			' sample matches: 02/29/2084 / 01/31/2000 / 11/30/2000 
			' sample non-matches: 	02/29/2083 / 11/31/2000 / 01/32/2000 

				objRegExp.Pattern		= "(((0[13578]|10|12)([-./])(0[1-9]|[12][0-9]|3[01])([-./])(\d{4}))|((0[469]|11)([-./])([0][1-9]|[12][0-9]|30)([-./])(\d{4}))|((2)([-./])(0[1-9]|1[0-9]|2[0-8])([-./])(\d{4}))|((2)(\.|-|\/)(29)([-./])([02468][048]00))|((2)([-./])(29)([-./])([13579][26]00))|((2)([-./])(29)([-./])([0-9][0-9][0][48]))|((2)([-./])(29)([-./])([0-9][0-9][2468][048]))|((2)([-./])(29)([-./])([0-9][0-9][13579][26])))"
	
			case "EMAIL_ADDRESS"
			' sample matches: asmith@mactec.com / foo12@foo.edu / bob.smith@foo.tv 
			' sample non-matches: joe / @foo.com / a@a 
			
				objRegExp.Pattern		= "^([a-zA-Z0-9_\-\.\47]+)@((\[[0-9]{1,3}\.[0-9]{1,3}\.[0-9]{1,3}\.)|(([a-zA-Z0-9\-]+\.)+))([a-zA-Z]{2,7}|[0-9]{1,3})(\]?)$"
					
				'The next line is supposed to be an RFC 2822 address compliant validation expression
				'objRegExp.Pattern		= "^(?:[\w\!\#\$\%\&\'\*\+\-\/\=\?\^\`\{\|\}\~]+\.)*[\w\!\#\$\%\&\'\*\+\-\/\=\?\^\`\{\|\}\~]+@(?:(?:(?:[a-zA-Z0-9](?:[a-zA-Z0-9\-](?!\.)){0,61}[a-zA-Z0-9]?\.)+[a-zA-Z0-9](?:[a-zA-Z0-9\-](?!$)){0,61}[a-zA-Z0-9]?)|(?:\[(?:(?:[01]?\d{1,2}|2[0-4]\d|25[0-5])\.){3}(?:[01]?\d{1,2}|2[0-4]\d|25[0-5])\]))$
					
			case "ZIP"
			' sample matches: 78754 / 78754-1234 / G3H 6A3 
			' sample non-matches: 78754-12aA / 7875A / g3h6a3
				
				objRegExp.Pattern		= "^(\d{5}-\d{4}|\d{5})$|^([a-zA-Z]\d[a-zA-Z] \d[a-zA-Z]\d)$"
					
			case "CREDIT_CARD"
			' sample matches: 6011-1111-1111-1111 / 5423-1111-1111-1111 / 341111111111111 
			' sample non-matches: 4111-111-111-111 / 3411-1111-1111-111 / Visa 
				
				objRegExp.Pattern		= "^((4\d{3})|(5[1-5]\d{2})|(6011))-?\d{4}-?\d{4}-?\d{4}|3[4,7]\d{13}$"
					
			case "NAME"
			' sample matches: T.F. Johnson / John O'Neil / Mary-Kate Johnson
			' sample non-matches: sam_johnson / Joe--Bob Jones / dfjsd0rd 
				
				objRegExp.Pattern		= "^[a-zA-Z]+(([\'\,\.\- ][a-zA-Z ])?[a-zA-Z]*)*$"
				
			case "ADDRESS"
			' sample matches:  2222 Mock St. / 1 A St. / 555-1212  
			' sample non-matches: [A Street] / (3 A St.) / {34 C Ave.} 
				
				objRegExp.Pattern		= "^[a-zA-Z0-9\s.\-]+$"
					
			case "CURRENCY"
			' sample matches: $3,023,123.34 / 9,876,453 / 123456.78 
			' sample non-matches: 4,33,234.34 / $1.234 / abc
				
				objRegExp.Pattern		= "^\$?([0-9]{1,3},([0-9]{3},)*[0-9]{3}|[0-9]+)(.[0-9][0-9])?$"
					
			case else
				
				Response.Write("Invalid syntax used to call form validation function.")
				Response.End

		end select
				
		Validate_Input = objRegExp.Test(Expression)
		
	else
		
		Response.Write("Invalid syntax used to call form validation function.")
		Response.End
			
	end if

End Function


	' Get data from the form collection and assign to variables
	dim str_Customer_Email
	dim str_Customer_Phone
	dim str_Customer_Name
	dim str_Customer_Zip

	str_Customer_Email		= Request.Form("email")
	str_Customer_Phone		= Request.Form("phone")
	str_Customer_Name		= Request.Form("name")
	str_Customer_Zip		= Request.Form("zip")

	if not (Validate_Input(str_Customer_Email,"EMAIL_ADDRESS")) then response.write ("error")
	if not (Validate_Input(str_Customer_Phone,"US_PHONE")) then response.write ("error")
	if not (Validate_Input(str_Customer_Name,"NAME")) then response.write ("error")
	if not (Validate_Input(str_Customer_Zip,"ZIP")) then response.write ("error")

response.end
%>