Need help starting a card game..

<cfset session.Cards = 'Ace of Spades, Ace of Hearts, Ace of Clubs, Ace of Diamonds, Two of Spades, Two of Clubs, Two of Diamonds, Two of Hearts, Three of Spades, Three of Clubs, Three of Diamonds, 
Three of Hearts, Four of Spades, Four of Clubs, Four of Diamonds, Four of Hearts, Five of Diamonds, Five of Hearts, Five of Clubs, Six of Diamonds, Six of Hearts, Six of Clubs, Six of Spades, 
Seven of Hearts, Seven of Spades, Seven of Clubs, Seven of Diamonds, Eight of Hearts, Eight of Diamonds, Eight of Hearts, Eight of Clubs, Nine of Diamonds, Nine of Hearts, Nine of Clubs, Nine of 
Spades, Ten of Hearts, Ten of Clubs, Ten of Spades, Ten of Diamonds, Jack of Hearts, Jack of Diamonds, Jack of Clubs, Jack of Spades, Queen of Hearts, Queen of Diamonds, Queen of Clubs, Queen of Spades,
King of Diamonds, King of Hearts, King of Clubs, King of Spades'>

<cfparam name="session.player1cards" default="">

<cfloop from="1" to="5" index="i">
<cfset Random = RandRange(1,56)>
<cfset deal = #ListGetAt(session.cards, '#Random#')#>
<cfset session.player1cards = ListAppend(session.player1cards, "#deal#")>
<cfset session.Cards = ListDeleteAt(session.Cards, "#Random#")>
</cfloop>

<cfoutput>#session.player1cards#</cfoutput>

Initializing game...<br /> 
<cfset cardGame = createObject( 'component', 'CardGame' ).init() />
Game initialized...<br /><br /> 

Dealing 5 cards...<br />
<cfoutput>#cardGame.dealCards( 5 )#</cfoutput>

<cfcomponent name="CardGame" hint="I model a simple card game.">
	
	<cffunction name="init" access="public" returntype="CardGame" hint="Constructor.">
		<cfset resetDeck() />
		<cfreturn this />
	</cffunction>
	
	<cffunction name="resetDeck" access="public" returntype="void" output="false" hint="Builds the deck of cards.">
		<cfset var local = structNew() />
		<cfset variables.instance.deck = arrayNew(1) />
		<cfset local.suitList = "Spades,Hearts,Clubs,Diamonds" />
		<cfset local.cardValueList = "2,3,4,5,6,7,8,9,10,Jack,Queen,King,Ace" />
		<cfloop list="#local.suitList#" index="local.thisSuit">
			<cfloop list="#local.cardValueList#" index="local.thisValue">
				<cfset arrayAppend( variables.instance.deck, structNew() ) />
				<cfset local.currentDeckSize = arrayLen( variables.instance.deck ) />
				<cfset variables.instance.deck[local.currentDeckSize].suit = local.thisSuit />
				<cfset variables.instance.deck[local.currentDeckSize].value = local.thisValue />
			</cfloop>
		</cfloop>
		<cfset variables.instance.usedCardList = "" />
	</cffunction>
	
	<cffunction name="dealCards" access="public" returntype="string" output="false" hint="Deals out the specified number of cards.">
		<cfargument name="numberOfCards" type="numeric" required="true" hint="Number of cards to deal." />
		<cfset var local = structNew() />
		<cfset local.dealtCardOutput = "" />
		<cfloop from="1" to="#arguments.numberOfCards#" index="local.thisDealCard">
			<!--- Get a new card and determine it's suit and value --->
			<cfset local.currentCard = getCard() />
			<cfset local.currentCardSuit = variables.instance.deck[local.currentCard].suit />
			<cfset local.currentCardValue = variables.instance.deck[local.currentCard].value />
			
			<!--- Add the current card to the output text. --->
			<cfset local.dealtCardOutput = local.dealtCardOutput & "The #local.currentCardValue# of #local.currentCardSuit#<br />" />
		</cfloop> 
		<cfreturn local.dealtCardOutput />
	</cffunction>
	
	<cffunction name="getCard" access="private" returntype="any" output="false" hint="Get one card that hasn't been dealt yet.">
		<cfset var local = structNew() />
		
		<!--- Pick a random card. --->
		<cfset local.currentCard = randRange( 1, 52 ) />
		
		<!--- If the current card has not already been dealt we can use it and add it to the list of used cards. --->
		<cfif not listFind( variables.instance.usedCardList, local.currentCard )>
			<cfset variables.instance.usedCardList = listAppend( variables.instance.usedCardList, local.currentCard ) />
		
		<!--- Otherwise, call getCard() recursively until we get to a card that hasn't been used --->
		<cfelse>
			<cfset local.currentCard = getCard() />
		</cfif>
		
		<cfreturn local.currentCard />
	</cffunction>
	
</cfcomponent>