XML Driven TreeView

Private Sub Form_Load()
    Dim lDoc As DOMDocument
    Set lDoc = New DOMDocument40
    
    ' load doc
    lDoc.Load "C:\test.xml"
    
    ' add nodes
    AddNodes TreeView1, Nothing, lDoc.DocumentElement
End Sub

Private Sub AddNodes(pTreeView As TreeView, pTreeParent As Node, pDocNode As IXMLDOMElement)
    Dim lTreeNode As Node
    
    ' add our xml node to our tree (if no parent, then we are
    ' the root node
    If (Not pTreeParent Is Nothing) Then
        Set lTreeNode = pTreeView.Nodes.Add(pTreeParent, tvwChild, , pDocNode.baseName)
    Else
        Set lTreeNode = pTreeView.Nodes.Add(, , , pDocNode.baseName)
    End If
    
    ' (hint) save our xml node reference in your tag so we can easily
    ' access our xml node when you just got the TreeView node
    Set lTreeNode.Tag = pDocNode
    
    ' add all child nodes
    Dim lDocChildNode As IXMLDOMElement
    For Each lDocChildNode In pDocNode.SelectNodes("*")
        AddNodes pTreeView, lTreeNode, lDocChildNode
    Next
End Sub